編寫主類Main

接下來編寫主類Main的代碼。按照之前的設計，主程序主要有以下兩個功能：

創建棋盤

處理用戶的交互動作

下面先來實現***個功能。

1.創建棋盤

上一節使用了二維矩陣來描述地圖數據，其實編寫代碼沒那么復雜，直接用一個二維數組就可以實現這個功能，代碼如下：

var gameMap:Array = new Array();      
//每一行用一維數組來表示    
gameMap[0] = [BLACK, WHITE, WHITE, BLACK];  
gameMap[1] = [WHITE, BLACK, BLACK, WHITE];  
gameMap[2] = [WHITE, BLACK, BLACK, WHITE];  
gameMap[3] = [BLACK, WHITE, WHITE, BLACK]; 

BLACK和WHITE是兩個常量，這樣看起來更直觀。利用數組，正好將地圖上的信息全面展示出來，從中可以看到每個棋子的初始狀態及在棋盤上的位置，創建棋盤的工作就變得簡單多了，如代碼清單2-2所示。

代碼清單2-2　創建棋盤

column_number = 4;  
　var rowCount:uint = gameMap.length;  
　var rowArray:Array;  
　var i:uint, len:uint;  
　var grid:Grid;  
　//棋子的間距  
　var space:int = 10;  
　//根據數組創建棋盤  
　for ( var row:uint = 0; row < rowCount; row++)  
　{  
　        //獲取每一行的數據  
　        rowArray = gameMap[row];  
　        len = rowArray.length;  
　        for ( i = 0; i < len; i++)  
　        {  
　                //創建Grid，并賦予初始值。GRID_RADIUS常量定義了棋子的尺寸  
　                grid = new Grid(rowArray[i], GRID_RADIUS);  
　                //計算出棋子在棋盤上的編號  
　                grid.id = row * column_number + i;  
　                //設置棋子的坐標  
　                grid.x = i * (GRID_RADIUS*2 + space);  
　                grid.y = row * (GRID_RADIUS*2 + space);  
　                //將棋子放在一個容器中，方便管理  
　                grid_container.addChild(grid);  
　                //按照編號將棋子保存在數組中，待以后查找  
　                grids[grid.id] = grid;  
　        }  
　} 

在創建棋盤時，使用數組grids保存了對所有棋子的引用，且棋子在數組中的索引和棋子在棋盤上的編號一一對應，這樣在查找周邊棋子時，只需要計算出周邊棋子的id即可。

棋盤創建完畢后，接下來處理用戶交互動作。

2.處理用戶交互動作

由于所有的棋子都被放在同一個容器中，因此可以只對容器添加監聽器，而不用監聽每個棋子的鼠標事件，如代碼清單2-3所示。

代碼清單2-3　處理用戶交互動作

grid_container.addEventListener(MouseEvent.CLICK, onClickHandler);  
 
 private function onClickHandler(e:MouseEvent):void  
 {  
         //由于沒有其他地方監聽對象的鼠標事件，因此中止冒泡事件     
         e.stopImmediatePropagation();    
         var grid:Grid = e.target as Grid;  
         //只有單擊對象是棋子才執行后面的代碼  
         if ( grid == null) return;  
         //翻轉當前單擊的棋子  
         grid.doFlip();  
         //翻轉周圍的四個棋子，用一個臨時數組存放周圍棋子的id  
         var ids:Array = new Array(grid.id - column_number, grid.id + column_number);  
         //如果棋子是在最左端，則左邊是空的，反之左邊存在棋子  
         if ( grid.id % column_number != 0 )  
         {  
                 ids.push(grid.id - 1);  
         }  
         //如果棋子是在最右端，則右邊是空的，反之右邊存在棋子  
         if ( grid.id % column_number != (column_number-1) )  
         {  
                 ids.push(grid.id + 1);  
         }  
         //記錄下棋子的總數  
         var totalGrid:int = grids.length;  
         //循環數組，翻轉周圍棋子        
         for ( var i:uint = 0, len:uint = ids.length; i < len; i++)  
         {  
                 var index:int = ids[i];  
                 //上面或下面的棋子可能不存在，需要判斷，如果超過數組界限，則不存在  
                 if (index <0 || index >= totalGrid) continue;  
                 grid = grids[index];  
                 if ( grid != null )  
                 {  
                 grid.doFlip();  
                 }  
           }  
           //處理完棋子的翻轉后，***檢查當前棋子是不是都變白了      
           if ( isAllWhite() )  
           {  
                 //game over  
                 gameOver();  
           }  
 }